「iOS」の版間の差分

2012年11月17日 (土) 21:15時点における版

iOSとは？

iPad, iPhone, iPod touch に搭載されているOS。詳しくは以下のところを参照して下さい。

• iOS - アップル
• Wikipedia:IOS_(アップル)

iOS アプリケーション（iOS App）

iOSアプリは、(iTunes) App Storeから購入できる。

• iTunes サポート - アップル
• Wikipedia:App_Store

iOSアプリは /Users/username/Music/iTunes/iTunes Media/Mobile Applications/ といったディレクトリに.ipaのファイルとして保存されている。この.ipaファイルはzip圧縮されたもので（必要ならば拡張子を.zipに変更して）適当な解凍ツールで展開できる。展開して得られるプロパティリスト（.plist）のファイルからは、様々な情報が確認できる。

• 【コラム】OS X ハッキング! (283) 速攻GETした「iPhone 3G」をあれこれイジる (1) - マイナビニュース（2008-07-12）

.ipaファイルからURI（URL）スキーム名を調べるAppleScript（テキストエディットに出力）

set ipaFiles to choose file of type "com.apple.itunes.ipa" default location (alias ((path to music folder as string) & "iTunes:iTunes Media:Mobile Applications:")) with prompt "iOS Appファイル（.ipa）を選択して下さい" with multiple selections allowed
repeat with idx from 1 to (count every item of ipaFiles)
	set item idx of ipaFiles to POSIX path of item idx of ipaFiles
end repeat

repeat with ipaFile in ipaFiles
	
	do shell script "unzip -o " & quoted form of ipaFile & " iTunesMetadata.plist -d " & quoted form of POSIX path of (path to temporary items from user domain as string)
	set tmpiTunesMetadata to POSIX path of ((path to temporary items from user domain as string) & "iTunesMetadata.plist")
	do shell script "chmod u+r " & quoted form of tmpiTunesMetadata
	-- set appName to (do shell script "defaults read " & quoted form of tmpiTunesMetadata & " itemName") -- 日本語が\uxxxx、®が\256といった形式になってこのままではダメ
	tell application "System Events"
		-- get value of contents of property list file tmpiTunesMetadata
		set appName to value of property list item "itemName" of property list file tmpiTunesMetadata
	end tell
	-- set appName to (do shell script "/usr/libexec/PlistBuddy -c 'Print itemName' " & quoted form of tmpiTunesMetadata) -- これでもいい（日本語等もOK）
	
	set pathInfo to (do shell script "zipinfo -1 " & quoted form of ipaFile & " | grep -E 'Payload/[^/]+\\.app/Info\\.plist' | perl -pe 's/\\[/[[]/g'") -- unzipコマンドのためにパスに[が含まれる場合に[[]に置換しておく
	do shell script "unzip -jo " & quoted form of ipaFile & space & quoted form of pathInfo & " -d " & quoted form of POSIX path of (path to temporary items from user domain as string)
	tell application "System Events"
		set tmpInfo to property list file ((path to temporary items from user domain as string) & "Info.plist")
		set listSchemes to {}
		if (name of every property list item of tmpInfo) contains "CFBundleURLTypes" then
			repeat with aCFBundleURLType in (value of property list item "CFBundleURLTypes" of tmpInfo) as list
				set listSchemes to listSchemes & CFBundleURLSchemes of (aCFBundleURLType & {CFBundleURLSchemes:{}}) -- CFBundleURLSchemes は aCFBundleURLType になければ {} として追加
			end repeat
		end if
	end tell
	if listSchemes is {} then
		set theSchemes to "URIスキームなし"
	else
		set theSchemes to item 1 of listSchemes & ":"
		repeat with aScheme in rest of listSchemes
			set theSchemes to theSchemes & ", " & aScheme & ":"
		end repeat
	end if
	
	set theText to appName & " (" & (do shell script "basename " & quoted form of ipaFile) & ") => " & theSchemes & return
	tell application "TextEdit"
		try
			tell theDoc to make new paragraph at after last paragraph of it with data theText
		on error
			activate
			set theDoc to make new document
			tell theDoc to make new paragraph at after last paragraph of it with data theText
		end try
	end tell
	
end repeat

tell theDoc
	activate
	set msgText to "iOS Appファイル" & (count items of ipaFiles) & "個を調べ終わりました"
	display dialog msgText buttons {"OK"} giving up after 5 default button 1
	-- do shell script "say -v Kyoko " & msgText
end tell

URIスキーム

他のアプリを呼び出す方法の1つとして、URI（URL）が使われる。

• Apple Geeks 第72回：iPhone／iPadの「アプリ間連携」を活用する - ASCII.jp（2012-02-10）
• NSURL - iPhone Development Wiki
• x-callback-url

Wiki内の関連ページ

• iPhone